Nix/hosts/common/gpu-screen-recorder.nix

{ pkgs, ... }:

let
  gsr-save-replay = pkgs.writeShellScriptBin "gsr-save-replay" ''
    ${pkgs.killall}/bin/killall -SIGUSR1 gpu-screen-recorder
    OUTPUT_DIR="$HOME/${outputDir}"
    VIDEO_FILE=$(ls -t $OUTPUT_DIR | head -n1)
    ACTION=$(${pkgs.libnotify}/bin/notify-send -a 'GPU Screen Recorder' --action 'file=Watch Replay' --action 'dir=View All Replays' -i com.dec05eba.gpu_screen_recorder -t 3000 -u low 'Replay Saved' "$VIDEO_FILE")
    if [ "$ACTION" == "dir" ]; then
      xdg-open $OUTPUT_DIR
    elif [ "$ACTION" == "file" ]; then
      xdg-open $OUTPUT_DIR/$VIDEO_FILE
    fi
  '';

  outputDir = "Videos/Replays";
in
{
  environment.systemPackages = [
    gsr-save-replay
  ];

  security.wrappers."gsr-kms-server" = {
    # Required to start recording without password prompt
    capabilities = "cap_sys_admin+ep";
    group = "root";
    owner = "root";
    source = "${pkgs.gpu-screen-recorder}/bin/gsr-kms-server";
  };

  services.xserver.desktopManager.gnome = {
    # TODO: Figure out how to properly add custom keyboard shortcuts to GNOME, this doesn't seem to work for some reason
    extraGSettingsOverrides = ''
      [org/gnome/settings-daemon/plugins/media-keys]
      custom-keybindings=['/org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/gsr-save-replay/']

      [org.gnome.settings-daemon.plugins.media-keys.custom-keybindings.gsr-save-replay]
      binding='<Alt>F12'
      command='gsr-save-replay'
      name='GPU Screen Recorder - Save Replay'
    '';

    extraGSettingsOverridePackages = with pkgs; [ gnome.gnome-settings-daemon ];
  };

  systemd.user.services."gsr-replay" = {
    after = [ "graphical-session.target" ];
    description = "GPU Screen Recorder replay service";
    enable = false; # Disabled by default to save resources
    serviceConfig = {
      Environment = [
        "AUDIO_CODEC=opus"
        "CODEC=auto"
        "CONTAINER=mkv"
        "FRAMERATE=60"
        "MAKEFOLDERS=no"
        "QUALITY=very_high"
        "REPLAYDURATION=300"
        "WINDOW=screen"
      ];
      ExecStart = pkgs.writeShellScript "start-gpu-screen-recorder-replay" ''
        ${pkgs.gpu-screen-recorder}/bin/gpu-screen-recorder -a "$(${pkgs.pulseaudio}/bin/pactl get-default-sink).monitor" -a "$(${pkgs.pulseaudio}/bin/pactl get-default-source)" -ac "$AUDIO_CODEC" -c "$CONTAINER" -f "$FRAMERATE" -k "$CODEC" -mf "$MAKEFOLDERS" -o "${outputDir}" -q "$QUALITY" -r "$REPLAYDURATION" -v no -w "$WINDOW" $ADDITIONAL_ARGS
      '';
      Restart = "on-failure";
      RestartSec = "5s";
      Type = "simple";
    };
    wantedBy = [ "graphical-session.target" ];
  };

  systemd.user.services."gsr-audio-device-changer" = {
    after = [ "gsr-replay.service" ];
    description = "Restart GPU Screen Recorder replay service on audio device change";
    requires = [ "gsr-replay.service" ];
    serviceConfig = {
      ExecStart = pkgs.writeShellScript "gsr-restart-on-audio-device-change" ''
        ${pkgs.pulseaudio}/bin/pactl subscribe | while read -r event; do
          if [[ $event == *"Event 'change' on server"* ]]; then
            systemctl --user restart gsr-replay.service
          fi
        done
      '';
      Restart = "always";
      RestartSec = "5s";
      Type = "simple";
    };
    wantedBy = [ "gsr-replay.service" ];
  };
}