mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-22 11:54:30 -04:00
e42c17ee97
It turns out that `cargo`, with respect to registry dependencies, was ignoring the package versions locked in `Cargo.lock` because we changed the registry index URL. Therefore, every time `rustRegistry` would be updated, we'd always try to use the latest version available for every dependency and as a result the deps' SHA256 hashes would almost always have to be changed. To fix this, now we do a string substitution in `Cargo.lock` of the `crates.io` registry URL with our URL. This should be safe because our registry is just a copy of the `crates.io` registry at a certain point in time. Since now we don't always use the latest version of every dependency, the build of `cargo` actually started to fail because two of the dependencies specified in its `Cargo.lock` file have build failures. To fix the latter problem, I've added a `cargoUpdateHook` variable that gets ran both when fetching dependencies and just before building the program. The purpose of `cargoUpdateHook` is to do any ad-hoc updating of dependencies necessary to get the package to build. The use of the '--precise' flag is needed so that cargo doesn't try to fetch an even newer version whenever `rustRegistry` is updated (and therefore have to change depsSha256 as a consequence).
67 lines
1.7 KiB
Nix
67 lines
1.7 KiB
Nix
{ stdenv, cacert, git, rustc, cargo, rustRegistry }:
|
|
{ name, src, depsSha256, buildInputs ? [], cargoUpdateHook ? "", ... } @ args:
|
|
|
|
let
|
|
fetchDeps = import ./fetchcargo.nix {
|
|
inherit stdenv cacert git rustc cargo rustRegistry;
|
|
};
|
|
|
|
cargoDeps = fetchDeps {
|
|
inherit name src cargoUpdateHook;
|
|
sha256 = depsSha256;
|
|
};
|
|
|
|
in stdenv.mkDerivation (args // {
|
|
inherit cargoDeps rustRegistry cargoUpdateHook;
|
|
|
|
buildInputs = [ git cargo rustc ] ++ buildInputs;
|
|
|
|
configurePhase = args.configurePhase or "true";
|
|
|
|
postUnpack = ''
|
|
echo "Using rust registry from $rustRegistry"
|
|
(
|
|
cd $sourceRoot
|
|
ln -s $rustRegistry ./cargo-rust-registry
|
|
|
|
substituteInPlace Cargo.lock \
|
|
--replace "registry+https://github.com/rust-lang/crates.io-index" \
|
|
"registry+file:///proc/self/cwd/cargo-rust-registry"
|
|
|
|
eval "$cargoUpdateHook"
|
|
|
|
cargo fetch
|
|
cargo clean
|
|
)
|
|
'' + (args.postUnpack or "");
|
|
|
|
# TODO: Probably not the best way to do this, but it should work for now
|
|
prePatch = ''
|
|
for dir in ../deps/registry/src/*/pkg-config-*; do
|
|
[ -d "$dir" ] || continue
|
|
|
|
substituteInPlace "$dir/src/lib.rs" \
|
|
--replace '"/usr"' '"/nix/store/"'
|
|
done
|
|
'' + (args.prePatch or "");
|
|
|
|
buildPhase = args.buildPhase or ''
|
|
echo "Running cargo build --release"
|
|
cargo build --release
|
|
'';
|
|
|
|
checkPhase = args.checkPhase or ''
|
|
echo "Running cargo test"
|
|
cargo test
|
|
'';
|
|
|
|
doCheck = args.doCheck or true;
|
|
|
|
installPhase = args.installPhase or ''
|
|
mkdir -p $out/bin
|
|
for f in $(find target/release -maxdepth 1 -type f); do
|
|
cp $f $out/bin
|
|
done;
|
|
'';
|
|
})
|