mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-20 11:11:43 -04:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
118 lines
3.2 KiB
Nix
118 lines
3.2 KiB
Nix
{
|
|
lib,
|
|
callPackage,
|
|
cmake,
|
|
coreutils,
|
|
fetchFromGitHub,
|
|
libxml2,
|
|
llvmPackages,
|
|
stdenv,
|
|
testers,
|
|
zlib,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "zig";
|
|
version = "0.12.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ziglang";
|
|
repo = "zig";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-C56jyVf16Co/XCloMLSRsbG9r/gBc8mzCdeEMHV2T2s=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
(lib.getDev llvmPackages.llvm)
|
|
];
|
|
|
|
buildInputs =
|
|
[
|
|
libxml2
|
|
zlib
|
|
]
|
|
++ (with llvmPackages; [
|
|
libclang
|
|
lld
|
|
llvm
|
|
]);
|
|
|
|
# On Darwin, Zig calls std.zig.system.darwin.macos.detect during the build,
|
|
# which parses /System/Library/CoreServices/SystemVersion.plist and
|
|
# /System/Library/CoreServices/.SystemVersionPlatform.plist to determine the
|
|
# OS version. This causes the build to fail during stage 3 with
|
|
# OSVersionDetectionFail when the sandbox is enabled.
|
|
__impureHostDeps = lib.optionals stdenv.hostPlatform.isDarwin [
|
|
"/System/Library/CoreServices/.SystemVersionPlatform.plist"
|
|
"/System/Library/CoreServices/SystemVersion.plist"
|
|
];
|
|
|
|
outputs = [
|
|
"out"
|
|
"doc"
|
|
];
|
|
|
|
cmakeFlags = [
|
|
# file RPATH_CHANGE could not write new RPATH
|
|
(lib.cmakeBool "CMAKE_SKIP_BUILD_RPATH" true)
|
|
# ensure determinism in the compiler build
|
|
(lib.cmakeFeature "ZIG_TARGET_MCPU" "baseline")
|
|
# always link against static build of LLVM
|
|
(lib.cmakeBool "ZIG_STATIC_LLVM" true)
|
|
];
|
|
|
|
env.ZIG_GLOBAL_CACHE_DIR = "$TMPDIR/zig-cache";
|
|
|
|
doInstallCheck = true;
|
|
|
|
# strictDeps breaks zig when clang is being used.
|
|
# https://github.com/NixOS/nixpkgs/issues/317055#issuecomment-2148438395
|
|
strictDeps = !stdenv.cc.isClang;
|
|
|
|
# Zig's build looks at /usr/bin/env to find dynamic linking info. This doesn't
|
|
# work in Nix's sandbox. Use env from our coreutils instead.
|
|
postPatch = ''
|
|
substituteInPlace lib/std/zig/system.zig \
|
|
--replace "/usr/bin/env" "${lib.getExe' coreutils "env"}"
|
|
'';
|
|
|
|
postBuild = ''
|
|
stage3/bin/zig run ../tools/docgen.zig -- ../doc/langref.html.in langref.html --zig $PWD/stage3/bin/zig
|
|
'';
|
|
|
|
postInstall = ''
|
|
install -Dm444 langref.html -t $doc/share/doc/zig-${finalAttrs.version}/html
|
|
'';
|
|
|
|
installCheckPhase = ''
|
|
runHook preInstallCheck
|
|
|
|
$out/bin/zig test --cache-dir "$TMPDIR/zig-test-cache" -I $src/test $src/test/behavior.zig
|
|
|
|
runHook postInstallCheck
|
|
'';
|
|
|
|
passthru = {
|
|
hook = callPackage ./hook.nix { zig = finalAttrs.finalPackage; };
|
|
cc = callPackage ../cc.nix { zig = finalAttrs.finalPackage; };
|
|
stdenv = callPackage ../stdenv.nix { zig = finalAttrs.finalPackage; };
|
|
tests = {
|
|
version = testers.testVersion {
|
|
package = finalAttrs.finalPackage;
|
|
command = "zig version";
|
|
};
|
|
};
|
|
};
|
|
|
|
meta = {
|
|
description = "General-purpose programming language and toolchain for maintaining robust, optimal, and reusable software";
|
|
changelog = "https://ziglang.org/download/${finalAttrs.version}/release-notes.html";
|
|
homepage = "https://ziglang.org/";
|
|
license = lib.licenses.mit;
|
|
mainProgram = "zig";
|
|
maintainers = with lib.maintainers; [ andrewrk ] ++ lib.teams.zig.members;
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
})
|