mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-21 11:43:11 -04:00
6d646062c8
https://github.com/flatpak/xdg-desktop-portal-gtk/releases/tag/1.15.0 https://github.com/flatpak/xdg-desktop-portal-gtk/releases/tag/1.15.1 https://github.com/flatpak/xdg-desktop-portal-gtk/compare/1.14.1...1.15.1 - Dropped most GNOME-specific portals. - Switched to Meson as build system. - With Autotools, all portals except for `settings` and `appchooser` were disabled by default. Now, all four optional portals are `auto`-enabled so we need to disable them match the previous behaviour. Changelog-reviewed-by: Jan Tojnar <jtojnar@gmail.com>
59 lines
1.3 KiB
Nix
59 lines
1.3 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitHub
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, xdg-desktop-portal
|
|
, gtk3
|
|
, gnome
|
|
, gnome-desktop
|
|
, glib
|
|
, wrapGAppsHook
|
|
, gsettings-desktop-schemas
|
|
, buildPortalsInGnome ? true
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "xdg-desktop-portal-gtk";
|
|
version = "1.15.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "flatpak";
|
|
repo = "xdg-desktop-portal-gtk";
|
|
rev = finalAttrs.version;
|
|
sha256 = "sha256-uXVjKsqoIjqJilJq8ERRzEqGKbkzc+Zl6y+37CAcYro=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
wrapGAppsHook
|
|
];
|
|
|
|
buildInputs = [
|
|
glib
|
|
gtk3
|
|
xdg-desktop-portal
|
|
] ++ lib.optionals buildPortalsInGnome [
|
|
gsettings-desktop-schemas # settings exposed by settings portal
|
|
gnome-desktop
|
|
gnome.gnome-settings-daemon # schemas needed for settings api (mostly useless now that fonts were moved to g-d-s, just mouse and xsettings)
|
|
];
|
|
|
|
mesonFlags = lib.optionals (!buildPortalsInGnome) [
|
|
"-Dwallpaper=disabled"
|
|
"-Dsettings=disabled"
|
|
"-Dappchooser=disabled"
|
|
"-Dlockdown=disabled"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Desktop integration portals for sandboxed apps";
|
|
maintainers = with maintainers; [ jtojnar ];
|
|
platforms = platforms.linux;
|
|
license = licenses.lgpl21Plus;
|
|
};
|
|
})
|