mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-20 11:11:43 -04:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
62 lines
1.7 KiB
Nix
62 lines
1.7 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchurl
|
|
, pkgs
|
|
, appimageTools
|
|
}:
|
|
let
|
|
pname = "pinokio";
|
|
version = "1.3.4";
|
|
src = fetchurl {
|
|
x86_64-darwin = {
|
|
url = "https://github.com/pinokiocomputer/pinokio/releases/download/${version}/Pinokio-${version}.dmg";
|
|
hash = "sha256-Il5zaVWu4icSsKmMjU9u1/Mih34fd+xNpF1nkFAFFGo=";
|
|
};
|
|
x86_64-linux = {
|
|
url = "https://github.com/pinokiocomputer/pinokio/releases/download/${version}/Pinokio-${version}.AppImage";
|
|
hash = "sha256-/E/IAOUgxH9RWpE2/vLlQy92LOgwpHF79K/1XEtSpXI=";
|
|
};
|
|
}.${stdenv.system} or (throw "Unsupported system: ${stdenv.system}");
|
|
|
|
appimageContents = appimageTools.extractType2 { inherit pname version src; };
|
|
|
|
meta = {
|
|
homepage = "https://pinokio.computer";
|
|
description = "Browser to install, run, and programmatically control ANY application automatically";
|
|
license = lib.licenses.mit;
|
|
maintainers = with lib.maintainers; [ ByteSudoer ];
|
|
platforms = [ "x86_64-darwin" "x86_64-linux" ];
|
|
mainProgram = "pinokio";
|
|
sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
|
|
};
|
|
in
|
|
|
|
if stdenv.hostPlatform.isDarwin then
|
|
stdenv.mkDerivation
|
|
{
|
|
inherit pname version src meta;
|
|
|
|
sourceRoot = ".";
|
|
|
|
nativeBuildInputs = with pkgs; [ undmg ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p "$out/Applications"
|
|
mv Pinokio.app $out/Applications/
|
|
runHook postInstall
|
|
'';
|
|
}
|
|
else
|
|
appimageTools.wrapType2 {
|
|
inherit pname version src meta;
|
|
|
|
extraInstallCommands = ''
|
|
mkdir -p $out/share/pinokio
|
|
cp -a ${appimageContents}/{locales,resources} $out/share/pinokio
|
|
cp -a ${appimageContents}/usr/share/icons $out/share/
|
|
install -Dm 444 ${appimageContents}/pinokio.desktop -t $out/share/applications
|
|
'';
|
|
|
|
}
|