mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-24 12:10:33 -04:00
da752902c1
There's a bugfix important for some auto-signer setups. https://gitlab.labs.nic.cz/knot/knot-dns/-/tags/v2.9.5 $ nix build -f nixos/release-combined.nix nixos.tests.knot.x86_64-linux
61 lines
1.6 KiB
Nix
61 lines
1.6 KiB
Nix
{ stdenv, fetchurl, pkgconfig, gnutls, liburcu, lmdb, libcap_ng, libidn2, libunistring
|
|
, systemd, nettle, libedit, zlib, libiconv, libintl
|
|
, autoreconfHook
|
|
}:
|
|
|
|
let inherit (stdenv.lib) optional optionals; in
|
|
|
|
# Note: ATM only the libraries have been tested in nixpkgs.
|
|
stdenv.mkDerivation rec {
|
|
pname = "knot-dns";
|
|
version = "2.9.5";
|
|
|
|
src = fetchurl {
|
|
url = "https://secure.nic.cz/files/knot-dns/knot-${version}.tar.xz";
|
|
sha256 = "1109a8ba212ff8ddfdbaf44a6f8fc13a2b880a98a9e54c19112ba72a1aacbf76";
|
|
};
|
|
|
|
outputs = [ "bin" "out" "dev" ];
|
|
|
|
configureFlags = [
|
|
"--with-configdir=/etc/knot"
|
|
"--with-rundir=/run/knot"
|
|
"--with-storage=/var/lib/knot"
|
|
];
|
|
|
|
patches = [
|
|
# Don't try to create directories like /var/lib/knot at build time.
|
|
# They are later created from NixOS itself.
|
|
./dont-create-run-time-dirs.patch
|
|
];
|
|
|
|
nativeBuildInputs = [ pkgconfig autoreconfHook ];
|
|
buildInputs = [
|
|
gnutls liburcu libidn2 libunistring
|
|
nettle libedit
|
|
libiconv lmdb libintl
|
|
# without sphinx &al. for developer documentation
|
|
]
|
|
++ optionals stdenv.isLinux [ libcap_ng systemd ]
|
|
++ optional stdenv.isDarwin zlib; # perhaps due to gnutls
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
CFLAGS = [ "-O2" "-DNDEBUG" ];
|
|
|
|
doCheck = true;
|
|
doInstallCheck = false; # needs pykeymgr?
|
|
|
|
postInstall = ''
|
|
rm -r "$out"/lib/*.la
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Authoritative-only DNS server from .cz domain registry";
|
|
homepage = "https://knot-dns.cz";
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.vcunat ];
|
|
};
|
|
}
|