mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-25 12:23:52 -04:00
2cbfdb8ff4
Tested using the pure-darwin alternate stdenv on Yosemite. I need this change for gnupg to build. Otherwise, I get this error: ``` configure: *** *** The system does not provide a working iconv function. Please *** install a suitable library; for example GNU Libiconv which is *** available at: *** http://ftp.gnu.org/gnu/libiconv/ *** configure: error: *** *** Required libraries not found. Please consult the above messages *** and install them before running configure again. *** builder for ‘/nix/store/pvzqmfzc05ifmvi0vglyl2xlkcdgh6c2-gnupg-2.1.6.drv’ failed with exit code 1 ``` cc: @wkennington
43 lines
1.3 KiB
Nix
43 lines
1.3 KiB
Nix
{ fetchurl, stdenv, pkgconfig, libgcrypt, libassuan, libksba, libiconv, npth
|
|
, autoreconfHook, gettext, texinfo, pcsclite
|
|
|
|
# Each of the dependencies below are optional.
|
|
# Gnupg can be built without them at the cost of reduced functionality.
|
|
, pinentry ? null, x11Support ? true
|
|
, adns ? null, gnutls ? null, libusb ? null, openldap ? null
|
|
, readline ? null, zlib ? null, bzip2 ? null
|
|
}:
|
|
|
|
with stdenv.lib;
|
|
|
|
assert x11Support -> pinentry != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "gnupg-2.1.6";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnupg/gnupg/${name}.tar.bz2";
|
|
sha256 = "1zcj5vsrc64zyq7spnx2xlxlq6wxaf5bilpf6gbkp7qr8barlnay";
|
|
};
|
|
|
|
postPatch = stdenv.lib.optionalString stdenv.isLinux ''
|
|
sed -i 's,"libpcsclite\.so[^"]*","${pcsclite}/lib/libpcsclite.so",g' scd/scdaemon.c
|
|
'';
|
|
|
|
buildInputs = [
|
|
pkgconfig libgcrypt libassuan libksba libiconv npth
|
|
autoreconfHook gettext texinfo
|
|
readline libusb gnutls adns openldap zlib bzip2
|
|
];
|
|
|
|
configureFlags = optional x11Support "--with-pinentry-pgm=${pinentry}/bin/pinentry";
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = http://gnupg.org;
|
|
description = "a complete and free implementation of the OpenPGP standard";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ wkennington ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|