mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-10-20 11:11:43 -04:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
74 lines
2 KiB
Nix
74 lines
2 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, autoreconfHook
|
|
, doxygen
|
|
, pkg-config
|
|
, enableUdev ? stdenv.hostPlatform.isLinux && !stdenv.hostPlatform.isStatic
|
|
, udev
|
|
, libobjc
|
|
, IOKit
|
|
, Security
|
|
, withExamples ? false
|
|
, withStatic ? false
|
|
, withDocs ? stdenv.buildPlatform.canExecute stdenv.hostPlatform
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libusb";
|
|
version = "1.0.27";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "libusb";
|
|
repo = "libusb";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-OtzYxWwiba0jRK9X+4deWWDDTeZWlysEt0qMyGUarDo=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ] ++ lib.optionals withDocs [ "doc" ];
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
autoreconfHook
|
|
] ++ lib.optionals withDocs [ doxygen ];
|
|
propagatedBuildInputs =
|
|
lib.optional enableUdev udev ++
|
|
lib.optionals stdenv.hostPlatform.isDarwin [ libobjc IOKit Security ];
|
|
|
|
dontDisableStatic = withStatic;
|
|
|
|
# libusb-1.0.rc:11: fatal error: opening dependency file .deps/libusb-1.0.Tpo: No such file or directory
|
|
dontAddDisableDepTrack = stdenv.hostPlatform.isWindows;
|
|
|
|
configureFlags =
|
|
lib.optional (!enableUdev) "--disable-udev"
|
|
++ lib.optional (withExamples) "--enable-examples-build";
|
|
|
|
postBuild = lib.optionalString withDocs ''
|
|
make -C doc
|
|
mkdir -p "$doc/share/doc/libusb"
|
|
cp -r doc/api-1.0/* "$doc/share/doc/libusb/"
|
|
'';
|
|
|
|
preFixup = lib.optionalString enableUdev ''
|
|
sed 's,-ludev,-L${lib.getLib udev}/lib -ludev,' -i $out/lib/libusb-1.0.la
|
|
'';
|
|
|
|
postInstall = lib.optionalString withExamples ''
|
|
mkdir -p $out/{bin,sbin,examples/bin}
|
|
cp -r examples/.libs/* $out/examples/bin
|
|
ln -s $out/examples/bin/fxload $out/sbin/fxload
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://libusb.info/";
|
|
description = "cross-platform user-mode USB device library";
|
|
longDescription = ''
|
|
libusb is a cross-platform user-mode library that provides access to USB devices.
|
|
'';
|
|
platforms = platforms.all;
|
|
license = licenses.lgpl21Plus;
|
|
maintainers = with maintainers; [ prusnak realsnick ];
|
|
};
|
|
}
|